jdIXTbDNJbpjrT9JFUXDwRebEyRI3zWNRv55P1Mf
Favoriler

Windows Lisans Kodu Nasıl Öğrenilir?

Windows Lisans Kodu Nasıl Öğrenilir?

Windows işletim sistemine ait bir bilgisayarınız var ve ürün anahtarını nasıl öğrenebilirim sorusuna cevap arıyorsunuz. İşte tam da bu içeriğimiz size göre. Microsoft tarafından geliştirilen Windows işletim sisteminde daha önce satın aldığınız ürün anahtarına artık erişiminiz olmadığında, sürüm yükselttiğinizde ya da başka bir bilgisayara aktarma gibi bir durum söz konusu olduğunda lisans koduna ihtiyacımız olacak. Bu lisans kodlarını "Hakkında" kısmından baktığımızda bizlere göstermiyor fakat bazı metotlar sayesinde ortaya çıkarılabiliyor. Dilerseniz lisans kodunun nasıl bulunduğuna bakalım.

Tüm Windows sürümleri ile uyumlu metotlardır.

Not Defteri ile Lisans Kodu Öğrenme

  1. Masaüstüne gelip sırasıyla Sağ Tık > Yeni > Metin Belgesi oluşturuyoruz.
  2. Hemen altta kutuda bulunan kodları Metin Belgesinin içine yapıştırıyoruz.
  3. Option Explicit
    Dim objshell,path,DigitalID, Result
    Set objshell = CreateObject("WScript.Shell")
    'Set registry key path
    Path = "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\"
    'Registry key value
    DigitalID = objshell.RegRead(Path & "DigitalProductId")
    Dim ProductName,ProductID,ProductKey,ProductData
    'Get ProductName, ProductID, ProductKey
    ProductName = "Product Name: " & objshell.RegRead(Path & "ProductName")
    ProductID = "Product ID: " & objshell.RegRead(Path & "ProductID")
    ProductKey = "Installed Key: " & ConvertToKey(DigitalID)
    ProductData = ProductName  & vbNewLine & ProductID  & vbNewLine & ProductKey
    'Show messbox if save to a file
    If vbYes = MsgBox(ProductData  & vblf & vblf & "Save to a file?", vbYesNo + vbQuestion, "BackUp Windows Key Information") then
    Save ProductData
    End If
    'Convert binary to chars
    Function ConvertToKey(Key)
    Const KeyOffset = 52
    Dim isWin8, Maps, i, j, Current, KeyOutput, Last, keypart1, insert
    'Check if OS is Windows 8
    isWin8 = (Key(66) \ 6) And 1
    Key(66) = (Key(66) And &HF7) Or ((isWin8 And 2) * 4)
    i = 24
    Maps = "BCDFGHJKMPQRTVWXY2346789"
    Do
    Current= 0
    j = 14
    Do
    Current = Current* 256
    Current = Key(j + KeyOffset) + Current
    Key(j + KeyOffset) = (Current \ 24)
    Current=Current Mod 24
    j = j -1
    Loop While j >= 0
    i = i -1
    KeyOutput = Mid(Maps,Current+ 1, 1) & KeyOutput
    Last = Current
    Loop While i >= 0
    keypart1 = Mid(KeyOutput, 2, Last)
    insert = "N"
    KeyOutput = Replace(KeyOutput, keypart1, keypart1 & insert, 2, 1, 0)
    If Last = 0 Then KeyOutput = insert & KeyOutput
    ConvertToKey = Mid(KeyOutput, 1, 5) & "-" & Mid(KeyOutput, 6, 5) & "-" & Mid(KeyOutput, 11, 5) & "-" & Mid(KeyOutput, 16, 5) & "-" & Mid(KeyOutput, 21, 5)
    End Function
    'Save data to a file
    Function Save(Data)
    Dim fso, fName, txt,objshell,UserName
    Set objshell = CreateObject("wscript.shell")
    'Get current user name
    UserName = objshell.ExpandEnvironmentStrings("%UserName%")
    'Create a text file on desktop
    fName = "C:\Users\" & UserName & "\Desktop\WindowsUrunAnahtariHadicoo.txt"
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set txt = fso.CreateTextFile(fName)
    txt.Writeline Data
    txt.Close
    End Function
  4. Farklı Kaydet seçeneğine tıklıyoruz ve açılan pencerede Kayıt Türü yazan seçeneği Tüm Dosyalar olarak düzeltiyoruz. Dosya adını ise WindowsLisans.vbs yapıyoruz.
  5. Kaydet diyerek pencereyi kapatıyoruz. Masaüstüne geldiğimizde WindowsLisans yazan dosyaya çift tıkladığımızda lisans kodu karşımıza çıkmış olacak. Dilerseniz açılan pencereye Yes diyerek lisans kodunu masaüstünde belge şeklinde kaydedebilirsiniz.

Komut İstemi ile Lisans Kodu Öğrenme

  1. Başlat menüsü yanında yer alan Arama kutusuna tıklayıp Komut İstemi yazıyoruz.
  2. Komut İstemi sonucu göründüğünde sağ kısımda yer alan(dilerseniz Komut İstemi dosyasına da sağ tıklayabilirsiniz) Yönetici olarak çalıştır yazısına tıklayın.
  3. Açılan pencereye başağıdaki metni kopyalayıp yapıştıralım.
  4. wmic path SoftwareLicensingService get OA3xOriginalProductKey
  5. Enter tuşuna bastığımızda lisans kodu karşımıza çıkmış olacak.

Yukarıda verilen yöntemler sayesinde Windows lisans anahtarınızı öğrenebilirsiniz.

Yorum Yaz

Yorum Yaz

Google Hesabı ile yapılan yorumunuza gelen yanıtlardan haberdar olmak istiyorsanız "Bana Bildir" seçeneğini işaretleyebilirsiniz.